Zuletzt geändert: 2018-08-25

Der Sketch um den Ds18b20 über die Adressen anzusprechen.

Ds18b20Array.ino

// ****************************************************************
// Sketch Esp8266 DS18b20 Adressen Array
// created: Jens Fleischer, 2018-08-25
// last mod: Jens Fleischer, 2018-08-25
// For more information visit: https://fipsok.de
// ****************************************************************
// Hardware: Esp8266
// Getestet auf: Nodemcu, Wemos D1 Mini Pro
/******************************************************************
  Copyright (c) 2018 Jens Fleischer. All rights reserved.

  This file is free software; you can redistribute it and/or
  modify it under the terms of the GNU Lesser General Public
  License as published by the Free Software Foundation; either
  version 2.1 of the License, or (at your option) any later version.
  This file is distributed in the hope that it will be useful,
  but WITHOUT ANY WARRANTY; without even the implied warranty of
  MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  Lesser General Public License for more details.
*******************************************************************/
// Pin einstellen an dem die Ds18b20 Sensoren angeschlossen sind.
// Alle Adressen deiner Sensoren in das Array "DeviceAddress sensor[]" eintragen.
// Der Sketch prüft ob die Anzahl der Adressen mit der Anzahl der Sensoren übereinstimmt.
/**************************************************************************************/

#include <DallasTemperature.h>    // Version 3.8.0  https://github.com/milesburton/Arduino-Temperature-Control-Library
#include <OneWire.h>              // Version 2.3.4  https://github.com/PaulStoffregen/OneWire

const uint8_t ONE_WIRE_PIN = D6;     // Sensor Pin einstellen
// trage alle Adressen deiner Ds18b20, die am Sensorpin angeschlossen sind ein.
DeviceAddress sensor[] = { {0x28, 0xff, 0x33, 0x10, 0x81, 0x16, 0x04, 0x54} , {0x28, 0xff, 0x07, 0x6f, 0x30, 0x17, 0x04, 0x2e} , {0x28, 0xFF, 0x03, 0x18, 0x81, 0x16, 0x04, 0xCC}};

OneWire oneWire(ONE_WIRE_PIN);
DallasTemperature DS18B20(&oneWire);

void setup() {
  Serial.begin(115200);
  delay(100);
  Serial.printf("\nSketchname: %s\nBuild: %s\n", (__FILE__), (__TIMESTAMP__));
  DS18B20.begin();
  DS18B20.setWaitForConversion(false);
  DS18B20.requestTemperatures();
}

void loop() {
  static uint32_t letzteMillis = 0;
  auto aktuelleMillis = millis();
  if (aktuelleMillis - letzteMillis >= 2e3) {
    letzteMillis = aktuelleMillis;
    const byte anzahl = sizeof(sensor) / 8 ;
    if (anzahl == DS18B20.getDS18Count()) {
      Serial.println();
      for (int i = 0; i < anzahl; i++ ) {
        Serial.printf("%d. %.2f°C\t", i + 1, (float)DS18B20.getTemp(sensor[i]) / 128);
      }
    }
    else {
      Serial.println("Die Anzahl der Sensoren stimmt nicht überein.");
    }
    DS18B20.requestTemperatures();
  }
}

ESP Startseite