2018-12-10

Esp32 E-Mail als Arduino Tab.

Mail.ino

// ****************************************************************
// Sketch E-mail senden Modular(Tab) nicht blockierend
// created: Jens Fleischer, 2018-07-09
// last mod: Jens Fleischer, 2018-12-10
// ****************************************************************
// Hardware: ESP32
// Software: https://smtp2go.com/
/******************************************************************
  Copyright (c) 2018 Jens Fleischer. All rights reserved.

  This file is free software; you can redistribute it and/or
  modify it under the terms of the GNU Lesser General Public
  License as published by the Free Software Foundation; either
  version 2.1 of the License, or (at your option) any later version.
  This file is distributed in the hope that it will be useful,
  but WITHOUT ANY WARRANTY; without even the implied warranty of
  MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  Lesser General Public License for more details.
*******************************************************************/
// Diese Version von Mail sollte als Tab eingebunden werden.
// #include <WebServer.h> oder #include <WiFi.h> muss im Haupttab aufgerufen werden
// Die Übergabe der Nachricht an "sendmails(Stringobject);" erfolgt als String.
// Zum auswerten der Antwort vom Mailserver muss "emailResponse();" im loop(); stehen.
/**************************************************************************************/

#include "base64.h"

WiFiClient mailclient;

uint32_t mailsendezeit;
bool mailresponse = true, mailerror = false;

void sendmails(const String &message) {    // SMTP2GO Free hat ein Limit von 25 E-Mails pro Stunde / 1.000 E-Mails pro Monat
  const char* user = "deinUsername";            // https://www.smtp2go.com/
  const char* password = "deinPasswort";        // https://www.smtp2go.com/
  const char* emfaenger = "deineMailAdresse";   // Adresse zu der gesendet werden soll
  const char* betreff = "Wichtige Mitteilung! Von zu Hause!";
  const char* sender = "ESP32";
  const char* mailServer = "mail.smtp2go.com";
  const uint16_t  port = 2525;

  if (!mailclient.connect(mailServer, port)) {
    DEBUG("Verbindung zu " + (String)mailServer + "fehlgeschlagen.");
  }
  else {
    mailresponse = false;
    mailsendezeit = millis();
    mailclient.printf("EHLO\nAUTH LOGIN\n%s\n%s\nMAIL From: <RbL@rbl.io>\nRCPT To: <%s>\nDATA\n", base64::encode(user).c_str(), base64::encode(password).c_str(), emfaenger);
    mailclient.printf("To: <%s>\nFrom: %s <RbL@rbl.io>\nSubject: %s %s\n", emfaenger, sender, sender, betreff);
    mailclient.printf("Hallo!\nDer %s %s meldet.\n%s\n.\nQUIT\n", sender, WiFi.getHostname(), message.c_str());
  }
}

void emailResponse() {
  if (!mailresponse) {
    if (millis() - mailsendezeit > 3000) {
      DEBUG_F("Mail mailclient Timeout !");
      if (!mailerror) {
        mailerror = true;
        sendmails("Fehler beim Mail versenden.");    // Bei Zeitüberschreitung wird eine Zweite Mail gesendet
      }
      return;
    }
    if (mailclient.available()) {
      for (uint8_t i = 0; i < 18; i++) {
        String line = mailclient.readStringUntil('\n');
        if (line.startsWith("250 OK id=")) {    // wenn Zeile der Antwort mit "250 OK id=" beginnt war das Senden erfolgreich
          DEBUG_F("Antwort vom Mailserver in: " + String(millis() - mailsendezeit) + " ms");
          mailclient.stop();
          mailerror = false;
          mailresponse = true;
        }
      }
    }
  }
}

Zurück